This website requires JavaScript.

AWK 技巧

过滤记录

比较运算符 ==,!=, >, <, >=, <=

# 下面过滤条件为:第三列的值为0 && 第6列的值为LISTEN
awk '$3==0 && $6=="LISTEN" ' netstat.txt
awk ' $3>0 {print $0}' netstat.txt
# 引入的内建变量
awk '$3==0 && $6=="LISTEN" || NR==1 ' netstat.txt
# 格式化输出,跟 C 语言一样
awk '$3==0 && $6=="LISTEN" || NR==1 {printf "%-20s %-20s %s\n",$4,$5,$6}' netstat.txt

内建变量

|内建变量|说明| |-|-| |$0|当前记录(这个变量中存放着整个行的内容)| |$1~$n|当前记录的第n个字段,字段间由FS分隔| |FS|输入字段分隔符 默认是空格或Tab| |NF|当前记录中的字段个数,就是有多少列| |NR|已经读出的记录数,就是行号,从1开始,如果有多个文件话,这个值也是不断累加中。| |FNR|当前记录数,与NR不同的是,这个值会是各个文件自己的行号| |RS|输入的记录分隔符, 默认为换行符| |OFS|输出字段分隔符, 默认也是空格| |ORS|输出的记录分隔符,默认为换行符| |FILENAME|当前输入文件的名字|

输出行号

awk '$3==0 && $6=="ESTABLISHED" || NR==1 {printf "%02s %s %-20s %-20s %s\n",NR, FNR, $4,$5,$6}' netstat.txt

指定分隔符

awk  'BEGIN{FS=":"} {print $1,$3,$6}' /etc/passwd
# 等价于
awk  -F: '{print $1,$3,$6}' /etc/passwd
# 定多个分隔符
awk -F '[;:]'
# 以\t作为分隔符输出
awk  -F: '{print $1,$3,$6}' OFS="\t" /etc/passwd

字符串匹配

# 匹配FIN状态,其实 ~ 表示模式开始。/ /中是模式。这就是一个正则表达式的匹配。
awk '$6 ~ /FIN/ || NR==1 {print NR,$4,$5,$6}' OFS="\t" netstat.txt
# awk可以像grep一样的去匹配第一行
awk '/LISTEN/' netstat.txt
# 使用 “/FIN|TIME/” 来匹配 FIN 或者 TIME :
awk '$6 ~ /FIN|TIME/ || NR==1 {print NR,$4,$5,$6}' OFS="\t" netstat.txt
# 模式取反
awk '$6 !~ /WAIT/ || NR==1 {print NR,$4,$5,$6}' OFS="\t" netstat.txt
# 或
awk 'NR!=1{print > $6}' netstat.txt

拆分文件

awk 'NR!=1{if($6 ~ /TIME|ESTABLISHED/) print > "1.txt";
else if($6 ~ /LISTEN/) print > "2.txt";
else print > "3.txt" }' netstat.txt

统计

计算所有的C文件,CPP文件和H文件的文件大小总和

ls -l  *.cpp *.c *.h | awk '{sum+=$5} END {print sum}'

统计各个connection状态

awk 'NR!=1{a[$6]++;} END {for (i in a) print i ", " a[i];}' netstat.txt

统计每个用户的进程的占了多少内存

ps aux | awk 'NR!=1{a[$1]+=$6;} END { for(i in a) print i ", " a[i]"KB";}'

awk 脚本

在上面我们可以看到一个END关键字。END的意思是“处理完所有的行的标识”,即然说到了END就有必要介绍一下BEGIN,这两个关键字意味着执行前和执行后的意思,语法如下:

  • BEGIN{ 这里面放的是执行前的语句 }
  • END {这里面放的是处理完所有的行后要执行的语句 }
  • {这里面放的是处理每一行时要执行的语句} 为了说清楚这个事,我们来看看下面的示例:

假设有这么一个文件(学生成绩表):

$ cat score.txt
Marry   2143 78 84 77
Jack    2321 66 78 45
Tom     2122 48 77 71
Mike    2537 87 97 95
Bob     2415 40 57 62

awk脚本如下

$ cat cal.awk
#!/bin/awk -f
#运行前
BEGIN {
    math = 0
    english = 0
    computer = 0
 
    printf "NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL\n"
    printf "---------------------------------------------\n"
}
#运行中
{
    math+=$3
    english+=$4
    computer+=$5
    printf "%-6s %-6s %4d %8d %8d %8d\n", $1, $2, $3,$4,$5, $3+$4+$5
}
#运行后
END {
    printf "---------------------------------------------\n"
    printf "  TOTAL:%10d %8d %8d \n", math, english, computer
    printf "AVERAGE:%10.2f %8.2f %8.2f\n", math/NR, english/NR, computer/NR
}

执行结果


awk -f cal.awk score.txt 
# 或 ./cal.awk score.txt
NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL
---------------------------------------------
Marry  2143     78       84       77      239
Jack   2321     66       78       45      189
Tom    2122     48       77       71      196
Mike   2537     87       97       95      279
Bob    2415     40       57       62      159
---------------------------------------------
  TOTAL:       319      393      350
AVERAGE:     63.80    78.60    70.00

环境变量

和环境变量交互(使用-v参数和ENVIRON,使用ENVIRON的环境变量需要export)

$ x=5
 
$ y=10
$ export y
 
$ echo $x $y
5 10
 
$ awk -v val=$x '{print $1, $2, $3, $4+val, $5+ENVIRON["y"]}' OFS="\t" score.txt
Marry   2143    78      89      87
Jack    2321    66      83      55
Tom     2122    48      82      81
Mike    2537    87      102     105
Bob     2415    40      62      72

一些栗子

其输出第1列和第4例

awk '{print $1, $4}' netstat.txt

从file文件中找出长度大于80的行

awk 'length>80' file

按连接数查看客户端IP

netstat -ntu | awk '{print $5}' | cut -d: -f1 | sort | uniq -c | sort -nr
0条评论
avatar